如何仅对父节点中的特定子节点进行排序

Question

如果只对父节点中的特定元素进行排序，我需要做什么？我的输入看起来像这个

<?xml version="1.0" encoding="UTF-8"?>
<Companies>
<badCompany>badCompany</badCompany>
<badCompany>badCompany2</badCompany>
<company>Toyota</company>
<company>Mercedes</company>
<company>BMW</company>
<company>Mazda</company>
<badCompany>badCompany3</badCompany>
</Companies>

我想在Companies节点中对所有Company节点进行排序，将其他子节点留在它们的位置，这样输出看起来像这个

<?xml version="1.0" encoding="UTF-8"?>
<Companies>
<badCompany>badCompany</badCompany>
<badCompany>badCompany2</badCompany>
<company>BMW</company>   
<company>Mazda</company>
<company>Mercedes</company>
<company>Toyota</company> 
<badCompany>badCompany3</badCompany>
</Companies>

这是我的代码，但它对所有儿童进行排序

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns1="http://sap.com/xi/SAPGlobal20/Global" xmlns:n1="http://sap.com/xi/EWM/Global" version="2.0">
<xsl:output encoding="UTF-8" method="xml" version="1.0"/>
<xsl:template match="Companies">
<xsl:copy>
<xsl:apply-templates>
<xsl:sort/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>

<xsl:template match="node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

Answer 1

这里有一种方法：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/Companies">
<xsl:copy>
<xsl:for-each-group select="*" group-adjacent="name()"> 
<xsl:choose>
<xsl:when test="self::company">
<xsl:apply-templates select="current-group()">
<xsl:sort/>
</xsl:apply-templates>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="current-group()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>