在使用for_each创建模块时传递模块的输出

Question

这链接到我的上一个问题，单击链接查看我的代码的其余部分以及它如何组合在一起:使用具有for_each集合的模块的输出值

虽然答案有助于解决问题并允许我运行管道，但我认为由于VM在模块上使用for_each生成的方式存在错误。这将导致传递给network_security_rule的值不正确。下面是错误的示例:

Error: Error Creating/Updating Network Security Rule "nsr-sbox-http80" (NSG "module.fico_app_vm.linux_vm_nsg" / Resource Group "rg-sbox-app"): network.SecurityRulesClient#CreateOrUpdate: Failure sending request: StatusCode=404 -- Original Error: Code="ResourceNotFound" Message="The Resource 'Microsoft.Network/networkSecurityGroups/module.fico_app_vm.linux_vm_nsg' under resource group 'rg-sbox-app' was not found. For more details please go to https://aka.ms/ARMResourceNotFoundFix"
  on main.tf line 58, in resource "azurerm_network_security_rule" "fico-app-sr-80":
  58: resource "azurerm_network_security_rule" "fico-app-sr-80" {

outputs.tf

output "linux_vm_ips" {
  value = azurerm_network_interface.dwp_network_interface.private_ip_address
}
output "linux_vm_nsg" {
  value = azurerm_network_security_group.dwp_network_security_group.name
}

起初我认为这是因为NSG没有被创建，但我检查了控制台，它确实创建了它。问题是NSG是在模块中为每个VM创建的。虚拟机是通过遍历tfvars文件中的变量来创建的。如何将模块中创建的NSG名称传递给模块外部的安全规则?:

resource "azurerm_network_security_rule" "fico-app-sr-80" {
  name                        = "nsr-${var.environment}-${var.directorate}-${var.business_unit}-${var.vm_identifier}${var.instance_number}-http80"
  priority                    = 100
  direction                   = "Inbound"
  access                      = "Allow"
  protocol                    = "*"
  source_port_range           = "*"
  destination_port_range      = "80"
  source_address_prefixes     = ["module.fico_web_vm.linux_vm_ips"]
  destination_address_prefix  = "VirtualNetwork"
  resource_group_name         = azurerm_resource_group.rg_fico_app.name
  network_security_group_name = "module.fico_app_vm.linux_vm_nsg"
}

# Network Security Group
resource "azurerm_network_security_group" "network_security_group" {
  name                = "nsg-${var.environment}-${var.directorate}-${var.business_unit}-${var.vm_identifier}-${var.vm_name}"
  resource_group_name = var.resource_group
  location            = var.location
}

还需要注意的是，var.vm_name遍历每个map的键，这构成了NSG名称的一部分。

main.tf中的模块:

module "fico_app_vm" {
  for_each                     = var.app_servers
  source                       = "../modules/compute/linux_vm"
  source_image_id              = var.app_image_id
  location                     = var.location
  vm_name                      = each.key
  vm_identifier                = "${var.vm_identifier}${var.instance_number}"
  vm                           = each.value
  disks                        = each.value["disks"]
  resource_group               = azurerm_resource_group.rg_fico_app.name
  directorate                  = var.directorate
  business_unit                = var.business_unit
  environment                  = var.environment
  network_rg_identifier        = var.network_rg_identifier
  subnet_name                  = "sub-${var.environment}-${var.directorate}-${var.business_unit}-be01"
  diag_storage_account_name    = var.diag_storage_account_name
  ansible_storage_account_name = var.ansible_storage_account_name
  ansible_storage_account_key  = var.ansible_storage_account_key
  log_analytics_workspace_name = var.log_analytics_workspace_name
  backup_policy_name           = var.backup_policy_name
  enable_management_locks      = true
}

tfvars:

app_servers ={
  app-1 = {
    size           = "Standard_E2s_v3"
    admin_username = "xxx"
    public_key     = "xxx"
    disks          = [32, 32]
    zone_vm        = "1"
    zone_disk      = ["1"]
  }
}

Answer 1

我认为问题是你没有仔细阅读前面的答案。答案显示您需要像这样更改安全组名:

network_security_group_name = module.fico_app_vm.linux_vm_nsg

没有双引号。双引号表示它是一个字符串。但是您需要使用模块属性，而不是值为"module.fico_app_vm.linux_vm_nsg"的字符串。错误还会直接显示。

Answer 2

我意识到我的错误是什么。我需要改变这个:

network_security_group_name = "module.fico_app_vm.linux_vm_nsg"

network_security_group_name = module.fico_app_vm[each.key].linux_vm_nsg

但是我还需要引用源地址前缀中的值。因此，为了引用键，我创建了另一个变量并更改为:

source_address_prefixes     = ["module.fico_web_vm.linux_vm_ips"]

:

source_address_prefix       = module.fico_web_vm[each.value.web_server].linux_vm_ip

我还必须更改为source_address_prefix，这就是发生类型错误的原因!

安全规则现在看起来像这样:

resource "azurerm_network_security_rule" "fico-app-sr-80" {
  for_each                    = var.app_servers
  name                        = "nsr-${var.environment}-${var.directorate}-${var.business_unit}-${var.vm_identifier}${var.instance_number}-http80"
  priority                    = 100
  direction                   = "Inbound"
  access                      = "Allow"
  protocol                    = "*"
  source_port_range           = "*"
  destination_port_range      = "80"
  source_address_prefix       = module.fico_web_vm[each.value.web_server].linux_vm_ip
  destination_address_prefix  = "VirtualNetwork"
  resource_group_name         = azurerm_resource_group.rg_dwp_fico_app.name
  network_security_group_name = module.fico_app_vm[each.key].linux_vm_nsg

变量是这样的

app_servers = {
  app-1 = {
    size           = "Standard_E2s_v3"
    admin_username = "azureuser"
    public_key     = xxxx
    disks          = [32, 32]
    zone_vm        = "1"
    zone_disk      = ["1"]
    web_server     = "web-1"
  }
}