批处理文件:将两列的字符串合并到另一列中

Question

我目前正在尝试自动化csv数据的预处理过程。我的csv表如下所示：

id;      town;   nrlanes;   direction;   name;            x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   Scottland B10;   54529;   338288;   E332;
111002;  Wales;  2;         London;      London B12;      54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     Ireland B3;      54529;   338288;   E303;

我试图做的是覆盖列"；name"；列id(最后3位应该剪切！(和方向(+字符串"Ri."应该放在方向之前(的组合。结果表应该如下所示：

id;      town;   nrlanes;   direction;   name;                x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   129 Ri. Scottland;   54529;   338288;   E332;
111002;  Wales;  2;         London;      111 Ri. London;      54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     334 Ri. Ireland;     54529;   338288;   E303;

这就是我迄今为止所尝试的：

@echo off
REM for /f "tokens=1,2,3,4,5,6,7,8 delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do echo %%a;%%b;%%c;%%d;%%~a Ri. %%~d;%%e;%%f;%%g >> "%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"
(
for /F "tokens=1-8* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
set id=%%a
set id_cut=%id:~-3%
set merged_columns=%id_cut% Ri. %%~d
echo %%a;%%b;%%c;%%d;%%e;%merged_columns%;%%f;%%g
)
)>> "%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

我在另一个线程中读到%var_name:~-3%会剪切字符串的最后三位数字，这正是我所需要的。以下是我的bat文件版本的结果：

id;      town;   nrlanes;   direction;   ;   x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   ;   54529;   338288;   E332;
111002;  Wales;  2;         London;      ;   54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     ;   54529;   338288;   E303;

正如你所看到的；name"；是空的，并且列名"也是空的；name"；是空的。我在这里做错了什么？有什么建议吗？

Answer 1

您需要delayedexpansion

注意，我必须用!替换%来扩展变量，这些变量在带括号的循环中是set。我还假设你没有所有的空白？

@echo off
setlocal enabledelayedexpansion
(for /F "skip=1 tokens=1-6* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
set "id=%%a"
echo %%a;%%b;%%c;%%d;!id:~0,-3! Ri. %%~d;%%f;%%g
)
)>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

最后，考虑您的结果将对标头产生什么影响，如果不需要这样做，则需要skip=1，然后修改标头以满足您的需要。以下是保留原始标题的示例：

@echo off
setlocal enabledelayedexpansion
for /F "delims=" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
(echo %%a)>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%" & goto :file
)
:file
(for /F "skip=1 tokens=1-6* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
set "id=%%a"
echo %%a;%%b;%%c;%%d;!id:~0,-3! Ri. %%~d;%%f;%%g
)
)>>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"