OCaml函数显然可以工作，但不会返回预期的结果

Question

谁能帮忙？我是OCaml的初学者，我正在尝试执行打开集合的操作。有了一个集合[(1, 4); (2, 5); (3, 6)]，我想得到出口[(1,2,3), (4,5,6)]。我使用的是一个用Haskell测试过的脚本，它起作用了，但在OCaml中，它没有显示结果。我哪里错了？我不知道我的错误在哪里。

let fst num1 num2 =
match num1, num2 with
| (x, y) -> x;;
let snd num1 num2 =
match num1, num2 with
| (x, y) -> y;;
let rec dcp_base list1 list2 list3 =
match list1, list2, list3 with
| (xs, ys, []) -> (xs, ys)
| (xs, ys, z :: zs) -> dcp_base (xs @ [fst z]) (ys @ [snd z]) zs;; 
let descompact list =
match list with
| [] -> ([], [])
| xs -> dcp_base [] [] xs;;

Answer 1

问题在于您对fst和snd的重新定义。它们是不需要的，因为它们已经在标准库中定义，并且在具有这些名称的范围内。但他们也错了。您的实现采用两个参数，并通过创建一个中间元组(而不是直接创建一个单元组参数(来迂回地选择第一个或第二个参数。因此，当您将其应用于单个元组参数时，它将返回一个部分应用的函数，该函数需要第二个参数。

您可以通过从代码中删除fst和snd的定义来解决这个问题，但如果您绝对想重新实现它，它应该看起来更像这样：

let fst (x, _) = x;;
let snd (_, y) = y;;

Answer 2

您的fst和snd函数实际上很奇怪，因为您需要两个参数来返回第一个或第二个。我想你想得到一对中的第一个或第二个元素，所以你应该写(从最详细到最不详细(

(* too much details *)
let fst num = match num with (x, y) -> x
let snd num = match num with (x, y) -> y
(* let's use the wildcards *)
let fst num = match num with (x, _) -> x
let snd num = match num with (_, y) -> y
(* do we really need num? *)
let fst = function (x, _) -> x
let snd = function (_, y) -> y
(* do we really need to match on a single pattern? *)
let fst (x, _) = x
let snd (_, y) = y

它应该起作用。

附带说明一下，fst和snd已经存在于标准库中，但尝试自己实现它们永远不会错

第二点要注意的是，通常不建议在列表末尾追加(不是尾部递归，而是强制程序遍历整个列表以在末尾追加元素(。相反，您可以在列表的开头添加每个新元素，并反转最终列表：

let rec dcp_base list1 list2 list3 =
match list1, list2, list3 with
| (xs, ys, []) -> (List.rev xs, List.rev  ys)
| (xs, ys, z :: zs) -> dcp_base (fst z :: xs) (snd z :: ys) zs;; 

实际上，由于OCaml非常强大，您根本不需要fst和snd：

let rec dcp_base list1 list2 list3 =
match list1, list2, list3 with
| (xs, ys, []) -> (List.rev xs, List.rev  ys)
| (xs, ys, (x, y) :: zs) -> dcp_base (x :: xs) (y :: ys) zs;; 

证明：

let rec dcp_base list1 list2 list3 =
match list1, list2, list3 with
| (xs, ys, []) -> (List.rev xs, List.rev  ys)
| (xs, ys, (x, y) :: zs) -> dcp_base (x :: xs) (y :: ys) zs;; 
let descompact list =
match list with
| [] -> ([], [])
| xs -> dcp_base [] [] xs;;
descompact [(1, 4); (2, 5); (3, 6)];;
- : int list * int list = ([1; 2; 3], [4; 5; 6])