如何让 Neo4J 在条件创建后继续

Question

创建节点集合后，某些节点还应根据条件附加关系。在下面的示例中，条件是用WHERE n.number > 3模拟的，节点是简单的数字：

WITH [2, 3, 4] as numbers
UNWIND numbers AS num
CREATE(n:Number {number: num})
WITH collect(n) AS nodes
UNWIND nodes AS n
WITH nodes, n WHERE n.number > 3
CREATE (n)-[:IM_SPECIAL]->(n)
RETURN nodes

其中返回：

╒════════════════════════════════════════╕
│"nodes"                                 │
╞════════════════════════════════════════╡
│[{"number":2},{"number":3},{"number":4}]│
└────────────────────────────────────────┘
Added 3 labels, created 3 nodes, set 3 properties, created 1 relationship, started streaming 1 records in less than 1 ms and completed after 1 ms.

我的问题是，除非我至少有被过滤器捕获的这些"特殊"节点之一，否则不会返回任何内容。可以通过将输入数字更改为[1, 2, 3]来模拟问题，即使创建了节点(它们应该创建)，也会返回空结果(无节点)：

<empty result>
Added 3 labels, created 3 nodes, set 3 properties, completed after 2 ms.

我可能完全错误地处理了这个问题，但我已经用尽了我的谷歌技能......我错过了什么Neo4J密码魔法？

Answer 1

有关条件密码执行的文档 - 在 4.1+ 中使用相关子查询描述了如何在不需要 Apoc 的情况下解决此问题：

WITH [2, 3, 4] AS numbers
UNWIND numbers AS num
CREATE(n:Number {number: num})
WITH n
CALL {
WITH n
WITH n WHERE n.number > 3
CREATE (n)-[:IM_SPECIAL]->(n)
RETURN count(n)
}
RETURN collect(n) AS nodes

感谢Sanjay Singh和Jose Bachoy让我走上正轨。

Answer 2

WITH nodes， n 其中 n.number> 3

Cypher 查询的每个子句都必须生成一个结果，供查询的后续行使用。如果从 [1,2,3] 开头，则上面的行不会产生任何结果。

为了您的目的，这将起作用。

WITH [1,2,3,4] as numbers
UNWIND numbers AS num
CREATE(n:Number {number: num})
WITH n
CALL apoc.do.when(n.number>3,
'CREATE (n)-[:IM_SPECIAL]->(n) RETURN n',
'RETURN n',
{n:n}
)
YIELD value as m
WITH collect(m) AS nodes
RETURN nodes