Windows Batch SET with Variable Substring Length?

Question

举个简单的例子:

@ECHO OFF
SET /P phrase="Enter Word : "
SET /a rnum=%random% %%10 +1
ECHO %phrase%
ECHO %rnum%
SET rchar=%phrase:~0,%rnum%%
ECHO %rchar%
Pause

我只想传递rnum变量来从用户输入的单词的左边选择一个字符到那个随机字符

我似乎不知道如何将其作为变量传递。

我尝试了enabledelayedexpansion，没有运气:

@ECHO OFF
SET /P Phrase="Enter Word : "
SET /a rnum=%random% %%10 +1
ECHO %phrase%
ECHO %rnum%
setlocal enabledelayedexpansion
SET rchar=!phrase:~0,%rnum%!
endlocal
ECHO %rchar%
Pause

那么我如何传递rnum作为一个变量在这个实例中?谢谢你的帮助。

Answer 1

下面是对示例延迟展开代码的一个简单修改，它显示了维护endlocal以外的变量值的一种方法:

@ECHO OFF
SET /P "phrase=Enter Word : "
SET /A rnum = %RANDOM% %% 10 + 1
ECHO %phrase%
ECHO %rnum%
SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%G IN ("!phrase:~0,%rnum%!") DO ENDLOCAL & SET "rchar=%%~G"
ECHO rchar=%rchar%
PAUSE

只要最终用户不开始输入带有问题字符的字符串，上面的示例应该没问题。如果您想让它在这种情况下更健壮一些，那么下面的代码可能会有所帮助:

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
:AskString
Rem Get interactive string input
Set "String="
Set /P String="Enter Word : "
If Not Defined String GoTo AskString
Set String
Rem Generate a random integer 1..10
Set /A "Integer = (%RANDOM% %% 10) + 1"
Set Integer
Rem Create a substring variable using %String% and %Integer%
Echo %%SubString%% = %%String:~0,%Integer%%%
SetLocal EnableDelayedExpansion
For /F Delims^=^ EOL^=^ UseBackQ %%G In ('"!String:~0,%Integer%!"') Do (
EndLocal
Set "SubString=%%~G"
)
Set SubString
Pause

请注意，上面的代码使用Set Variable来显示变量名和它的值。如果您的变量包含某些有害字符，仅使用Echo %Variable%可能不起作用，那么您最好在那时启用延迟扩展。

Answer 2

正如Compo已经评论的那样，您的endlocal的位置是问题所在。

你可以把endlocal移到echo

后面

@ECHO OFF
setlocal enabledelayedexpansion
SET /P Phrase="Enter Word : "
SET /a rnum=%random% %%10 +1
ECHO !phrase!
ECHO !rnum!
SET "rchar=!phrase:~0,%rnum%!"
ECHO !rchar!
endlocal