对三个输入数字排序

Question

我在看这个作业:

编写一个程序，接受三个输入并按升序输出

我使用了以下LMC模拟器:https://www.101computing.net/LMC/#

这是我到目前为止所做的:

INP 901 Input num1
STA 318 Store num1 in address 18
INP 901 Input num2
STA 319 Store num2 in address 19
INP 901 Input num3
STA 320 Store num3 in address 20
SUB 219 Subtract num2 from num3
BRP 810 Jump to address 10 if it is zero or positive (J1)
LDA 519 Load num2 from address 19
STA 320 Store num3 in address 20
LDA 520 Load num3 from address 20 (J1)
SUB 218 Subtract num1 from num3
BRP 815 Jump to address 18 if it is zero or positive (J2)
LDA 518 Load num1 from address 18
STA 320 Store num3 in address 20
LDA 520 Load num3 from address 20 (J2)
OUT 902 Output result
HLT 000 Stop program
DAT     Data num1
DAT     Data num2
DAT     Data num3

我只找到了最大的数，但我不知道如何将它们按升序排列。

我怎样才能以正确的顺序输出其他两个值?

Answer 1

首先对您提供的代码进行一些注释:

• 该代码不解析你链接到的模拟器。这是因为您将助记符(3个字母的代码)与指令代码(3位数的数字)结合在一起。你应该用助记法。例如，写INP，而不是INP 901。
• 使用标签。例如，不写STA 318，前面应该写STA 18，而是写STA num1，并在相应的DAT行定义该标签:num1 DAT。请注意，您链接到的模拟器甚至不接受没有标签的DAT。
• 在注释的开头使用分隔字符(如#或;)。尽管一些模拟器并不介意您在编写注释时不使用分隔符，但最好还是使用它。此外，您链接到的模拟器似乎不支持注释。
• 注释时，注释要超越对指令的描述。例如，将Stop program作为注释放在HLT旁边是没有用的。这应该是显而易见的。取而代之的是注释，解释算法中指令的更高目的。例如:num3是否大于num2?我想在第一个BRP上评论一下。

因此，将上述更改应用到您的代码中，您将得到以下内容:

#input: 3 2 1
INP
STA num1
INP
STA num2
INP
STA num3
comp23   LDA num3 # is num2 <= num3?
SUB num2
BRP sorted23 # yes
LDA num2 # no: copy it to num3
STA num3
sorted23 LDA num3 # is num1 <= num3?
SUB num1
BRP output # yes: we're done
LDA num1 # no: copy it to num3
STA num3
output   LDA num3 # output the greatest
OUT
HLT
num1     DAT
num2     DAT
num3     DAT
<script src="https://cdn.jsdelivr.net/gh/trincot/lmc@v0.815/lmc.js"></script>

这将打印输入中最大的值。现在要对输入进行排序，需要交换对值。对于交换，您可以使用第四个变量(temp)。例如，要将num2与num3交换，您可以这样写:

LDA num3
STA temp # temporary save num3 here
LDA num2
STA num3 # now both are the same value
LDA temp # but we still have a copy...
STA num2

您可以排序3个数字，最多3次交换。如果有第三次交换，它将与第一次交换的类型相同。

这是如何工作的:

#input:3 2 1
INP
STA num1
INP
STA num2
INP
STA num3
comp23    LDA num3 # is num2 <= num3?
SUB num2
BRP sorted23 # yes
LDA num3 # no: swap num2 and num3
STA temp
LDA num2
STA num3
LDA temp
STA num2
sorted23  LDA num2 # is num1 <= num2
SUB num1
BRP sorted123 # yes: we're done
LDA num2 # no: swap num1 and num2
STA temp
LDA num1
STA num2
LDA temp
STA num1
BRA comp23 # repeat once
sorted123 LDA num1 # output the sorted list
OUT
LDA num2
OUT
LDA num3
OUT
HLT
num1      DAT
num2      DAT
num3      DAT
temp      DAT # used for swapping
<script src="https://cdn.jsdelivr.net/gh/trincot/lmc@v0.815/lmc.js"></script>

在我看来，你所指的模拟器不是最好的。我在这个答案中使用的是这里——我是它的作者。