SPARQL:找到具有相同三元组的主题?

Question

我正在尝试识别具有完全相同的三元组"集合"的主题。在此示例数据中，:Set2应标识为与:Set1的唯一完全匹配，而:Set1和:Set3由于值:VAL_E而不是完全匹配。

@prefix :  <https://www.example.org/Eg#>.
:Set1 :hasValue  :VAL_A, :VAL_B, :VAL_C, :VAL_D .
:Set2 :hasValue  :VAL_A, :VAL_B, :VAL_C, :VAL_D .
:Set3 :hasValue  :VAL_A, :VAL_B, :VAL_C, :VAL_D, :VAL_E .
:Set4 :hasValue  :VAL_A, :VAL_B .
:Set5 :hasValue  :VAL_F, :VAL_G, :VAL_H, :VAL_I, :VAL_J .

我在 StackOverflow 上找到了示例 SPARQL，它标识了:Set1和其他集合之间匹配的单个三元组，甚至是匹配的数量，但没有识别一组三元组作为一个整体的精确匹配。我希望需要FILTER NOT EXISTS和!SAMETERM的组合，但我无法获得正确的语法。

更新： 我从 @StanislavKralin 中改编了 SPARQL，以找到与 ：Set1 相同的其他集合。它几乎有效。

SELECT DISTINCT  ?s2 {
:Set1 ?p ?o .
?s2 ?p ?o .
FILTER NOT EXISTS { :Set1 ?p1 ?o1 . FILTER NOT EXISTS { ?s2 ?p1 ?o1 } }
FILTER NOT EXISTS { ?s2 ?p2 ?o2 . FILTER NOT EXISTS { :Set1 ?p2 ?o2 } } # omits match from :Set3 to :Set1
FILTER (STR(:Set1) < STR(?s2))
}

但是，我的查询结果包括：Set4，这是不正确的。

:Set2
:Set4

我错过了什么？

[更新]正如下面的评论所述，斯坦尼斯拉夫在Stardog社区论坛上提供了进一步的解释和代码：https://community.stardog.com/t/unexpected-sparql-filter-results/2745/14，以及Pavel Klinov解释Stardog当前行为的其他信息。正如您在那里读到的，已打开一张票证以供解决。同时，斯坦尼斯拉夫提供的这段代码提供了正确的结果：

SELECT DISTINCT ?s1 ?s2 {
?s1 ?p ?o .   
?s2 ?p ?o .
FILTER NOT EXISTS {
?s1 ?p ?o . 
?s2 ?p ?o . 
?s1 ?p1 ?o1 . 
FILTER NOT EXISTS { ?s2 ?p1 ?o1 } }
FILTER NOT EXISTS {
?s1 ?p ?o . 
?s2 ?p ?o .
?s2 ?p2 ?o2 . 
FILTER NOT EXISTS { ?s1 ?p2 ?o2 } }
FILTER (STR(?s1) < STR(?s2))
}

Answer 1

在Apache Jena Fuseki和Ontotext GraphDB中测试：

SELECT DISTINCT ?s1 ?s2 {
?s1 ?p ?o .
?s2 ?p ?o .
FILTER NOT EXISTS { ?s1 ?p1 ?o1 . FILTER NOT EXISTS { ?s2 ?p1 ?o1 } }
FILTER NOT EXISTS { ?s2 ?p2 ?o2 . FILTER NOT EXISTS { ?s1 ?p2 ?o2 } }
FILTER (STR(?s1) < STR(?s2))
}

解释

设S1和S2分别以:s1和:s2为主语的三元组集合.
S1 ≡ S2是什么意思？这意味着S1 ⊆ S2和S2 ⊆ S1.
S1 ⊆ S2是什么意思？这意味着∀x(x ∈ S1 → x ∈ S2).
不幸的是，在SPARQL.
中没有类似∀('for all')的东西，但是，人们可以写¬∃x¬(x ∈ S1 → x ∈ S2)并使用SPARQL的NOT EXISTS.
最后，x ∈ S1可以翻译为:s1 ?p ?o。

另请参阅此答案。