我想做一些类似的事情
int n=0
for(int i=xs; i<xe; i++){
for(int j=ys; j<ye; j++){
n++
}
}
return n;
以Clojure的方式。由于所有值都是不可变的，我认为值n应该作为(可能(递归函数的参数传递。最好的方法是什么？
最接近代码的是
(defn f [xs xe ys ye]
(let [n (atom 0)]
(doseq [_ (range xs xe)
_ (range ys ye)]
(swap! n inc))
@n))
user> (f 1 10 2 20)
;;=> 162
但是，可变原子的方法根本就不是一成不变的。
它可能看起来像这样，有点像clojure方式：
(defn f [xs xe ys ye]
(count (for [_ (range xs xe)
_ (range ys ye)]
nil)))
#'user/f
user> (f 1 10 2 20)
;;=> 162
这实际上取决于你想做什么。正如@jas所注意到的，(* (- xe xs) (- ye ys))显然能更好地计算n，与你使用的语言无关(
你提到的递归解决方案是什么？它可能看起来像这样：
(defn f [xs xe ys ye]
(loop [n 0 i xs j ys]
(cond (== j ye) n
(== i xe) (recur n xs (inc j))
:else (recur (inc n) (inc i) j))))
#'user/f
user> (f 1 10 2 20)
;;=> 162
不要过度思考这个问题。当您真正需要可变状态时，您可以始终使用atom:
(defn calc
[xs ys]
(let [result (atom 0)]
(doseq [x xs]
(doseq [y ys]
(swap! result + (* x y))))
@result))
(let [xs [1 2 3]
ys [2 5 7 9]]
(calc xs ys))
结果
(calc xs ys) => 138
你也可以使用挥发性物质。它就像一个没有线程安全的原子。注意vswap!:的使用
(defn calc
[xs ys]
(let [result (volatile! 0)]
(doseq [x xs]
(doseq [y ys]
(vswap! result + (* x y))))
@result))
性能
在一个紧密的循环中，使用volatile会有所不同。一个例子：
(ns tst.demo.core
(:use tupelo.core tupelo.test)
(:require [tupelo.profile :as prof]))
(def N 100)
(def vals (vec (range N)))
(prof/defnp summer-atom []
(let [result (atom 0)]
(doseq [i vals]
(doseq [j vals]
(doseq [k vals]
(swap! result + i j k))))
@result))
(prof/defnp summer-volatile []
(let [result (volatile! 0)]
(doseq [i vals]
(doseq [j vals]
(doseq [k vals]
(vswap! result + i j k))))
@result))
(dotest
(prof/timer-stats-reset)
(dotimes [i 10]
(spyx (summer-atom))
(spyx (summer-volatile)))
(prof/print-profile-stats))
结果：
--------------------------------------
Clojure 1.10.2-alpha1 Java 15
--------------------------------------
Testing tst.demo.core
(summer-atom) => 148500000
(summer-volatile) => 148500000
...
---------------------------------------------------------------------------------------------------
Profile Stats:
Samples TOTAL MEAN SIGMA ID
10 2.739 0.273879 0.023240 :tst.demo.core/summer-atom
10 0.383 0.038313 0.041246 :tst.demo.core/summer-volatile
---------------------------------------------------------------------------------------------------
因此，它产生了大约10倍的差异。可能不值得，除非你做了至少一百万次这样的操作(100^3(。
有关数据结构的类似低级操作，请参阅瞬态！和朋友。
特别是将此列表中的Clojure CheatSheet作为书签
我认为在这里可以将reduce函数应用于for。在loop-processing-fn中做什么取决于您——它也可以是递归的。
(let [n-init 0 ;; your `n` variable
xs 10 xe 20 ys -5 ye 5 ;; loop(s) ranges
loop-processing-fn (fn [current-state [i j :as loop-data]]
(inc current-state) ;; anything here
) ;; processing function operating on state (n) and loop data
]
(reduce loop-processing-fn n-init (for [i (range xs xe)
j (range ys ye)]
[i j])))
;; => 100
脑海中浮现的是宏。我定义了一个宏for-state，我这样使用：
(def xs 0)
(def xe 9)
(def ys 1)
(def ye 4)
(for-state
i xs (< i xe) (inc i) n 0
(for-state
j ys (< j ye) (inc j) n n
(inc n)))
;; => 27
宏允许您添加仅使用函数难以构建的新构造。因此，如果你有几个这样的嵌套循环，定义一个像for-state这样的宏可能是一个选项：
(defmacro for-state [iter-var iter-init iter? iter-next
state-var state-init state-next]
`(loop [~iter-var ~iter-init
~state-var ~state-init]
(if ~iter?
(recur ~iter-next
~state-next)
~state-var)))
你可以随意调整。例如，您可以使用向量对宏参数进行分组，并对这些参数进行析构函数以提高可读性。