我想将一个使用文件(Excel文件(合并到Stata中的主文件中。可能很简单，但我不知道如何保存Excel文件转换为dta文件，这样我就可以在Stata中合并这两个数据集。
我已经阅读了xls2data命令，但我不确定我是否朝着正确的方向看。
您不需要使用xls2dta之类的特殊命令来转换文件。您只需将其导入Stata并以dta格式保存在临时文件中，然后就可以将该临时文件与您的dta文件合并。
这是一个可重复的例子。运行此代码所需要做的就是在代码开头更新local中的文件夹路径。您应该能够调整"；解决方案"；部分。
*Set this path to an example folder on your computer
local folder "C:Usersusernamemyfolder"
******************************************************************
*Prepare Excel example file
******************************************************************
*Use built in example data
sysuse auto, clear
*Rename all files but ID var make
foreach var of varlist _all {
if "`var'"!="make" rename `var' `var'_ex
}
*save in excel format
export excel "`folder'/autoexcel.xls", firstrow(variables) replace
******************************************************************
*Solution
******************************************************************
*Use built in example data
sysuse auto, clear
*Load the excelfile into a temporary .dta file
preserve
import excel "`folder'/autoexcel.xls", firstrow clear
tempfile autoexcel_tmp
save `autoexcel_tmp'
restore
*Merge the dta file in memory with tempfile of excel file in dta format
merge 1:1 make using `autoexcel_tmp'