如何确定接收方是否为流动性池?

Question

我正在创建一个令牌，当在流动性池中出售时，收取费用并消耗一定数量。

假设我有一个收件人地址，我如何检查它是否是一个流动性池?

我想我可以使用这个:https://docs.uniswap.org/protocol/V2/reference/smart-contracts/pair-erc-20但是我不确定哪个功能会起作用，或者是否有另一种方式。

Answer 1

您可以针对Uniswap Pair (V2)或Uniswap Pool (V3)接口测试地址，看它是否返回预期值。

更进一步，您可以将这些返回值传递回Uniswap Factory合约(地址可以在V2文档和V3文档中找到)，它根据输入值告诉您一个池地址。通过这种方式，您可以确定查询的地址实际上是一个Uniswap池，而不仅仅是从同名函数返回值的其他契约。

pragma solidity ^0.8;
import "https://github.com/Uniswap/v2-core/blob/master/contracts/interfaces/IUniswapV2Factory.sol";
import "https://github.com/Uniswap/v3-core/blob/main/contracts/interfaces/IUniswapV3Factory.sol";
import "https://github.com/Uniswap/v2-core/blob/master/contracts/interfaces/IUniswapV2Pair.sol";
import "https://github.com/Uniswap/v3-core/blob/main/contracts/interfaces/IUniswapV3Pool.sol";
contract MyContract {
IUniswapV2Factory constant v2Factory = IUniswapV2Factory(address(0x5C69bEe701ef814a2B6a3EDD4B1652CB9cc5aA6f));
IUniswapV3Factory constant v3Factory = IUniswapV3Factory(address(0x1F98431c8aD98523631AE4a59f267346ea31F984));
/**
* true on Ethereum mainnet - 0x0d4a11d5EEaaC28EC3F61d100daF4d40471f1852
* false on Ethereum mainnet - 0xdAC17F958D2ee523a2206206994597C13D831ec7
*/
function isUniswapV2Pair(address target) external view returns (bool) {
if (target.code.length == 0) {
return false;
}
IUniswapV2Pair pairContract = IUniswapV2Pair(target);
address token0;
address token1;
try pairContract.token0() returns (address _token0) {
token0 = _token0;
} catch (bytes memory) {
return false;
}
try pairContract.token1() returns (address _token1) {
token1 = _token1;
} catch (bytes memory) {
return false;
}
return target == v2Factory.getPair(token0, token1);
}
/**
* true on Ethereum mainnet - 0x4e68Ccd3E89f51C3074ca5072bbAC773960dFa36
* false on Ethereum mainnet - 0xdAC17F958D2ee523a2206206994597C13D831ec7
*/
function isUniswapV3Pool(address target) external view returns (bool) {
if (target.code.length == 0) {
return false;
}
IUniswapV3Pool poolContract = IUniswapV3Pool(target);
address token0;
address token1;
uint24 fee;
try poolContract.token0() returns (address _token0) {
token0 = _token0;
} catch (bytes memory) {
return false;
}
try poolContract.token1() returns (address _token1) {
token1 = _token1;
} catch (bytes memory) {
return false;
}
try poolContract.fee() returns (uint24 _fee) {
fee = _fee;
} catch (bytes memory) {
return false;
}
return target == v3Factory.getPool(token0, token1, fee);
}
}

我还添加了一个检查目标地址是否为合约的条件:if (target.code.length == 0)。如果是终端用户地址，则执行提前返回。

注意，这段代码只适用于部署了Uniswap的网络(例如，主网的本地分支，或者一些测试网)。在其他网络(如Remix VM模拟器)上，Uniswap契约不可达，这将导致调用的恢复。

Answer 2

在Uniswap V3

import "@uniswap/v3-core/contracts/interfaces/IUniswapV3Factory.sol";
address poolAddress = IUniswapV3Factory(_factory).getPool(
_token0,
_token1,
_fee
);

您可以从这里获得_factory地址https://docs.uniswap.org/protocol/reference/deployments。

getPool是一个映射

mapping(address => mapping(address => mapping(uint24 => address))) public override getPool;

调用IUniswapV3Factory(_factory).getPool时，如果键不存在，它将返回默认地址类型address(0)。所以你应该添加一个require条件

require(poolAddress!=address(0))

如果此条件通过，则表示您从映射中获得了有效的池地址。