如何在Delphi 10.3上不接受字符串中的特殊字符

Question

我正在为我的校本作业编写一个程序。它应该接受姓名作为string，接受工资输入作为integer，并告诉你是否难以辨认或能够参加聚会，并重复直到stop=9。

一切都很顺利，但问题是string变量接受错误的名称作为输入并继续。例如CCD_ 5。

我希望程序不接受这些输入，并写一行声明它不会继续使用除字符以外的任何名称。这也不应该添加一个数字来停止。源代码如下。

program Sba;
Uses
Windows;
var
FName,LName:String;
Stop,Salary:Integer;
//procedure Sleep(milliseconds: Cardinal); stdcall; external 'kernel32.dll'; //Added sleep as a procedure for delay
Begin
Repeat //Repeats until stop = 9
Writeln('Hi User,please Enter your First Name'); //Prompting user to enter their First initials
Readln(FName); //Attaches the string entered to the variable FName
Sleep(1000);//Delay 1second
Writeln('First Name entered');  //Lets the user know they have entered their first initials
Sleep(1000);
Writeln('Please Enter your Last name'); //Prompting user to enter their last initial
Readln(LName);  //Attaches the string entered to the variable LName
Sleep(1000);
Writeln('Last Name entered'); //Lets the user know they have entered their last initials
Sleep(800);
Writeln('Hi ',' ',FName,' ',LName); //Writes Line Hi (First Name) (Last Name)
Sleep(1000);
Writeln('Please enter The amount you have paid');//Prompts user for their payment
Readln(Salary); //Atttached value entered to Salary
Writeln('Reading your payment will be done in four seconds');
Sleep(4000);//delay 4 seconds
Writeln('Done!');
If (Salary<1000) Then
Begin
Writeln('You do not have sufficient funds to play in a section');
Sleep(1000);
End;
Sleep(1000);
If (Salary>=1000) AND (Salary<=2000) then //Testing conditions
Begin
Sleep(1000);
Writeln('Congrats, You are eligible to play in the Tribe Section'); //Tells use what section they are available to play in
End;
If (Salary>=2100) AND (Salary<=3000) then //Testing conditions
Begin
Sleep(1000);
Writeln('Congrats, You are eligible to play in the Poison Section');
End;
If (Salary>=3100) AND (Salary<=5000) then //Testing conditions
Begin
Sleep(1000);
Writeln('Congrats, You are eligible to play in the Harts Section');
End;
Writeln('Press enter to continue');
Readln;
Writeln('Enjoy your day ' , FName,'!');
Stop:=Stop+1; //Repeats until stop= 9
Sleep(1000);
Until Stop=9;//Repeats this 10 times
Writeln('Written By Timothy Adams 4-1');
Readln;
end.

Answer 1

由于这是家庭作业，我不会给你要求的东西。相反，我会给你一个更复杂的例子来学习。

首先，我们必须决定一个有效的名称是什么样子的。因为如果我们不知道什么名字才是有效的，我们肯定无法通过计算机编程来区分！

作为一个玩具示例，让我们假设一个名称是有效的iff:

1. 它只包含字母、空格和HYPHEN-MINUS(-(字符。[请注意，字符串中的所有内容都是一个字符。字符类的例子有字母、数字、空白和标点符号。因此，当你说字符串必须只包含"字符"时，你指的是其他内容，比如"只包含字母"。]

2. 它至少包含两个字母。

对于现实世界的应用程序来说，这还不够好。它将禁止使用许多有效的名称。但对于这个玩具例子来说，它已经足够好了。

让我们来实现它！

function IsValidName(const S: string): Boolean;
var
i, c: Integer;
begin
// The string must only contain letters, whitespace, and HYPHEN-MINUS
for i := 1 to S.Length do
if not (S[i].IsLetter or S[i].IsWhiteSpace or (S[i] = '-')) then
Exit(False);
// The string must contain at least two letters
c := 0;
for i := 1 to S.Length do
if S[i].IsLetter then
Inc(c);
if c < 2 then
Exit(False);
Result := True;
end;

研究这个函数，直到你完全理解它是如何工作的！

完成了吗？太棒了现在让我们利用它：

program Project1;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils,
Character;
var
Name: string;
function IsValidName(const S: string): Boolean;
begin
// same as above, won't repeat it here
end;
begin
try
try
Writeln('Hello! What is your name?');
while True do
begin
Readln(Name);
Name := Name.Trim;
if IsValidName(Name) then
begin
Writeln('Welcome, ', Name, '!');
Break;
end
else
Writeln('Surely that isn''t your real name? What is your actual name?');
end;
except
on E: Exception do
Writeln(E.ClassName, ': ', E.Message);
end;
finally
Writeln('Program about to end. Press Return to exit.');
Readln;
end;
end.

再说一遍，因为我为你做作业几乎违反了规则，所以我不会详细解释其中的逻辑。相反，我会让你弄清楚它是如何为自己工作的。这样你会学到更多。

更新：完整的程序应该如下所示：

program Project1;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils,
Character;
var
Name: string;
function IsValidName(const S: string): Boolean;
var
i, c: Integer;
begin
// The string must only contain letters, whitespace, and HYPHEN-MINUS
for i := 1 to S.Length do
if not (S[i].IsLetter or S[i].IsWhiteSpace or (S[i] = '-')) then
Exit(False);
// The string must contain at least two letters
c := 0;
for i := 1 to S.Length do
if S[i].IsLetter then
Inc(c);
if c < 2 then
Exit(False);
Result := True;
end;
begin
try
try
Writeln('Hello! What is your name?');
while True do
begin
Readln(Name);
Name := Name.Trim;
if IsValidName(Name) then
begin
Writeln('Welcome, ', Name, '!');
Break;
end
else
Writeln('Surely that isn''t your real name? What is your actual name?');
end;
except
on E: Exception do
Writeln(E.ClassName, ': ', E.Message);
end;
finally
Writeln('Program about to end. Press Return to exit.');
Readln;
end;
end.