我不确定是否可以发布这样一个后续问题，但我还是要这样做。
所以几天前我发布了这个问题:我如何删除Isabelle中所有子多集的出现?
我认为答案是伟大的，但当试图证明引理
lemma "applied1 {#''a'',''a'',''d'',''c'',''a'',''a'',''d'',''c''#} {#''a'',''a'',''c''#} ''f'' = {#''f'',''f'',''d'',''d''#}"
我真的卡住了。在展开def并应用一些简单的自动化之后，我发现我不能简单地做到这一点。所以我回到原来的函数，对它做了一些调整，这样如果输入导致无限循环，它什么也不返回。我以为这次会成功的，但伊莎贝尔还是无法证明终止。我很确定，很明显，size x不断地以size y的一个因子减少，并且不可能是负的，所以当size x = 0或y不再是x的子集时，它将最终终止。
fun applied2 :: "'a multiset ⇒ 'a multiset ⇒ 'a ⇒ 'a multiset option" where
"applied2 x y z = (if z ∈# y ∨ y = {#} then None else (if y ⊆# x then Some (plus {#z#} (the (applied2 (x - y) y z))) else Some x))"
是否有可能说服Isabelle这个函数终止使用function而不是fun?还是我必须考虑其他约束条件?
我相信看一下文档会给你正确的语法。
function applied2 :: "'a multiset ⇒ 'a multiset ⇒ 'a ⇒ 'a multiset option" where
"applied2 x y z = (if z ∈# y ∨ y = {#} then None else (if y ⊆# x then Some (plus {#z#} (the (applied2 (x - y) y z))) else Some x))"
by pat_completeness auto
termination
by (relation "measure (λ(x,y,z). size x)")
(auto simp: mset_subset_eq_exists_conv nonempty_has_size)
如果问题是证据，大锤会帮你找到的。
但是，我不明白您打算如何从applied2转到您真正想要的功能。真正的问题是决定论:你需要一个顺序来查看子集。Manuel的解决方案是使用Sup，但这确实是不可执行的。
如果您对非递归定义的唯一问题是如何将其应用于具体输入，我仍然认为我所说的可执行的替代定义是可行的。下面是证明我给出的两个非递归定义是等价的，以及在您上面给出的例子中的应用:
definition applied :: "'a multiset ⇒ 'a multiset ⇒ 'a ⇒ 'a multiset" where
"applied ms xs y = (if xs = {#} then ms else
(let n = Max {n. repeat_mset n xs ⊆# ms}
in ms - repeat_mset n xs + replicate_mset n y))"
lemma count_le_size: "count M x ≤ size M"
by (induction M) auto
lemma applied_code [code]:
"applied ms xs y = (if xs = {#} then ms else
(let n = (MIN x ∈set_mset xs. count ms x div count xs x)
in ms - repeat_mset n xs + replicate_mset n y))"
unfolding applied_def
proof (intro if_cong let_cong refl)
assume ne: "xs ≠ {#}"
have subset: "{n. repeat_mset n xs ⊆# ms} ⊆ {..size ms}"
proof safe
fix n assume n: "repeat_mset n xs ⊆# ms"
from ne obtain x where x: "x ∈# xs"
by auto
have "n * 1 ≤ n * count xs x"
using x by (intro mult_left_mono) auto
also have "… = count (repeat_mset n xs) x"
by simp
also have "… ≤ count ms x"
using n by (intro mset_subset_eq_count)
also have "… ≤ size ms"
by (rule count_le_size)
finally show "n ≤ size ms" by simp
qed
hence finite: "finite {n. repeat_mset n xs ⊆# ms}"
by (rule finite_subset) auto
show "Max {n. repeat_mset n xs ⊆# ms} = (MIN x∈set_mset xs. count ms x div count xs x)"
proof (intro antisym)
show "Max {n. repeat_mset n xs ⊆# ms} ≤ (MIN x∈set_mset xs. count ms x div count xs x)"
proof (rule Max.boundedI)
show "{n. repeat_mset n xs ⊆# ms} ≠ {}"
by (auto intro: exI[of _ 0])
next
fix n assume n: "n ∈ {n. repeat_mset n xs ⊆# ms}"
show "n ≤ (MIN x∈set_mset xs. count ms x div count xs x)"
proof (safe intro!: Min.boundedI)
fix x assume x: "x ∈# xs"
have "count (repeat_mset n xs) x ≤ count ms x"
using n by (intro mset_subset_eq_count) auto
also have "count (repeat_mset n xs) x = n * count xs x"
by simp
finally show "n ≤ count ms x div count xs x"
by (metis count_eq_zero_iff div_le_mono nonzero_mult_div_cancel_right x)
qed (use ne in auto)
qed (fact finite)
next
define m where "m = (MIN x∈set_mset xs. count ms x div count xs x)"
show "m ≤ Max {n. repeat_mset n xs ⊆# ms}"
proof (rule Max.coboundedI[OF finite], safe)
show "repeat_mset m xs ⊆# ms"
proof (rule mset_subset_eqI)
fix x
show "count (repeat_mset m xs) x ≤ count ms x"
proof (cases "x ∈# xs")
case True
have "count (repeat_mset m xs) x = m * count xs x"
by simp
also have "… ≤ (count ms x div count xs x) * count xs x"
unfolding m_def using ‹x ∈# xs› by (intro mult_right_mono Min.coboundedI) auto
also have "… ≤ count ms x"
by simp
finally show ?thesis .
next
case False
hence "count xs x = 0"
by (meson not_in_iff)
thus ?thesis by simp
qed
qed
qed
qed
qed
lemma replicate_mset_unfold:
assumes "n > 0"
shows "replicate_mset n x = {#x#} + replicate_mset (n - 1) x"
using assms by (cases n) auto
lemma
assumes "a ≠ c" "a ≠ f" "c ≠ f"
shows "applied {#a,a,c,a,a,c#} {#a,a,c#} f = mset [f, f]"
using assms
by (simp add: applied_code replicate_mset_unfold flip: One_nat_def)
value命令在这个例子中不起作用，因为a、c等都是自由变量。但是，如果您为它们创建一个特殊的数据类型，它就可以工作了:
datatype test = a | b | c | f
value "applied {#a,a,c,a,a,c#} {#a,a,c#} f"
(* "mset [f, f]" :: "test multiset" *)