我刚刚开始在Kotlin中学习Android,我正在创建一个笔记应用程序,只是为了学习目的。我想使用Room在我的数据库中存储已保存的笔记,所以我正在检查开发人员。我们有一些必要的依赖,我们必须添加到我们的build.gradle(模块)如上所述developer.android.com https://developer.android.com/training/data-storage/room#kts但是当我添加这些依赖项时,我有一个错误,我无法找出
在object类型org.gradle.api.internal.artifact .dsl.dependencies. defaultdependencyhandler
找不到参数[androidx.room:room-compiler:2.4.3]的方法ksp()
我与kapt有类似的错误,但我通过在我的build.gradle(模块)中添加必要的插件来解决它。现在我正在从我的构建中删除此实现。Gradle和前进的测试项目,但任何帮助将是感激的,谢谢。
在developer.android.com中提到的依赖项
dependencies {
val room_version = "2.4.3"
implementation("androidx.room:room-runtime:$room_version")
annotationProcessor("androidx.room:room-compiler:$room_version")
// To use Kotlin annotation processing tool (kapt)
kapt("androidx.room:room-compiler:$room_version")
// To use Kotlin Symbol Processing (KSP)
ksp("androidx.room:room-compiler:$room_version")
// optional - Kotlin Extensions and Coroutines support for Room
implementation("androidx.room:room-ktx:$room_version")
// optional - RxJava2 support for Room
implementation("androidx.room:room-rxjava2:$room_version")
// optional - RxJava3 support for Room
implementation("androidx.room:room-rxjava3:$room_version")
// optional - Guava support for Room, including Optional and ListenableFuture
implementation("androidx.room:room-guava:$room_version")
// optional - Test helpers
testImplementation("androidx.room:room-testing:$room_version")
// optional - Paging 3 Integration
implementation("androidx.room:room-paging:$room_version")
}
我build.gradle(模块)
plugins {
id 'com.android.application'
id 'org.jetbrains.kotlin.android'
id 'kotlin-android'
id 'kotlin-kapt'
}
android {
namespace 'android.example.mynotes'
compileSdk 32
defaultConfig {
applicationId "android.example.mynotes"
minSdk 21
targetSdk 32
versionCode 1
versionName "1.0"
testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
}
buildTypes {
release {
minifyEnabled false
proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
}
}
compileOptions {
sourceCompatibility JavaVersion.VERSION_1_8
targetCompatibility JavaVersion.VERSION_1_8
}
kotlinOptions {
jvmTarget = '1.8'
}
}
dependencies {
implementation 'androidx.core:core-ktx:1.7.0'
implementation 'androidx.appcompat:appcompat:1.5.1'
implementation 'com.google.android.material:material:1.7.0'
implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
testImplementation 'junit:junit:4.13.2'
androidTestImplementation 'androidx.test.ext:junit:1.1.5'
androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
def room_version = "2.4.3"
implementation "androidx.room:room-runtime:$room_version"
annotationProcessor "androidx.room:room-compiler:$room_version"
implementation "androidx.room:room-rxjava2:$room_version"
implementation "androidx.room:room-rxjava3:$room_version"
implementation "androidx.room:room-guava:$room_version"
testImplementation "androidx.room:room-testing:$room_version"
implementation("com.google.devtools.ksp:symbol-processing-api:1.8.0-1.0.8")
kapt "androidx.room:room-compiler:$room_version"
ksp("androidx.room:room-compiler:$room_version")
}
我build.gradle(项目)
plugins {
id 'com.android.application' version '7.3.1' apply false
id 'com.android.library' version '7.3.1' apply false
id 'org.jetbrains.kotlin.android' version '1.7.20' apply false
}
项目gradle.build
在plugins{ ... }
块中将kotlin gradle插件升级到1.8.0。
// Project level build file
plugins {
...
id 'org.jetbrains.kotlin.android' version '1.8.0' apply false
}
在App(module)上gradle.build文件中不需要设置kapt(),只需在dependencies{ ... }
块中添加ksp()
,并设置KSP插件
// App module build file
plugins{
...
id 'com.google.devtools.ksp' version '1.8.0-1.0.8'
}
dependencies {
...
// You don't need this
// kapt("androidx.room:room-compiler:$room_version")
ksp("androidx.room:room-compiler:$room_version")
...
}
确保您的kotlin gradle插件版本为1.8.0或更高
classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.8.0'
在应用级gradle文件中添加依赖项
id 'com.google.devtools.ksp' version '1.8.0-1.0.8'
最后,构建项目。
根据本文档
首先,在你的顶级build.gradle.kts文件中声明KSP插件。确保选择与项目Kotlin版本一致的KSP版本
plugins {
id("com.google.devtools.ksp") version "1.8.10-1.0.9" apply false
}
然后,在模块级build.gradle.kts文件中启用KSP:
plugins {
id("com.google.devtools.ksp")
}
首先,您需要在您的顶级构建(项目)中声明KSP插件。gradle。kt文件。请确保您选择的KSP版本与项目的Kotlin版本一致。
如果你正在使用Kotlin - build.gradle.kts(项目级别)
plugins {
id("com.google.devtools.ksp") version "1.8.10-1.0.9" apply false
}
如果你正在使用Groovy- build.gradle(项目级别)
plugins {
id 'com.google.devtools.ksp' version '1.8.10-1.0.9' apply false
}
然后启用KSP在模块级或应用级的build.gradle.kts文件中:
Kotlin - build.gradle.kts(模块级或应用级)
plugins {
id("com.google.devtools.ksp")
}
Groovy - build.gradle(模块级或应用级)
plugins {
id 'com.google.devtools.ksp'
}
用KSP替换注释处理器
//For .kts
dependencies {
//When you have no dependencies included with kapt in your module anymore, remove the kapt plugin.
//kapt("androidx.room:room-compiler:2.5.0")
ksp("androidx.room:room-compiler:2.5.0")
}
//For Groovy
dependencies {
//When you have no dependencies included with kapt in your module anymore, remove the kapt plugin.
//kapt 'androidx.room:room-compiler:2.5.0'
ksp 'androidx.room:room-compiler:2.5.0'
}
您还应该删除与kapt相关的任何剩余配置。
你可能会从Google codelab找到答案
1-添加插件到app/build.gradle
plugins {
...
// ksp for room
id 'com.google.devtools.ksp' version "1.8.21-1.0.11"
}
2-添加app/build.gradle中的依赖项
dependencies {
...
def room_version = "2.5.1"
implementation "androidx.room:room-runtime:$room_version"
ksp "androidx.room:room-compiler:$room_version"
implementation "androidx.room:room-ktx:$room_version"
}