如何添加.到applescript中路径的最后一部分?

Question

我正在重命名一个文件的名称，以便基本上从我的计算机的其他用户隐藏它，因为我很隐私的东西。我在applescript中这样做，并有一个我想要更改的文件名列表。我听说过分隔符，但不知道如何使用。如何在Applescript中改变这个-

/Users/username/Desktop/file.txt

到

/Users/username/Desktop/.file.txt

Answer 1

分隔符是用来帮助处理文本的，这在你的情况下并不是一个真正的问题。

要使用applescript重命名单个文件，首先使用它作为别名，然后将其名称设置为新的名称。

set fName to POSIX file "/Users/username/Desktop/file.txt"
set aName to fName as alias
tell application "Finder" to set name of aName to ".file.txt"

要从文本文档中重命名文件列表(假设每行一个文件)，请读取文档，创建其行列表，然后循环遍历该列表。在循环中，posix引用被强制转换为别名，使我们能够使用文件名属性。

use scripting additions
-- specify file containing list of files to rename
set pfListing to POSIX path of (path to desktop as text) & "lista.txt"
--> "/Users/username/Desktop/lista.txt"
-- Contains one entry per line, like this:
-- /Users/username/Desktop/file1.txt
-- /Users/username/Desktop/file2.txt
-- read contents into list of files
set fList to paragraphs of (get read pfListing)
--> {"/Users/username/Desktop/file1.txt", "/Users/username/Desktop/file2.txt"}
tell application "Finder"
repeat with fp in fList -- each file path
tell me to set afp to POSIX file (contents of fp) as alias
set name of afp to "." & name of afp
end repeat
end tell
--> /Users/username/Desktop/.file1.txt
--> /Users/username/Desktop/.file2.txt

如果您有一个重命名文件的列表，并且希望恢复到它们的原始名称，请将'set name…'行替换为:

set chgName to name of afp
set origName to text 2 thru -1 of chgName
set name of afp to origName