如何在Forth中访问阴影定义?

Question

当一个单词被重新定义时，是否有可能访问旧单词?

想象有一个词foo被定义和重新定义

: foo ( n -- 2*n ) 2* ;  ok
: foo ( n -- 2*n+1 ) foo 1+ ; redefined foo   ok
10 foo . 21  ok

foo在这里执行两个定义。

是否可以执行第一个定义("second-foo")?

21 second-foo . 42 ok

要see吗?

see second-foo
: foo
2* ; ok

Answer 1

访问阴影定义的一种简单方法是在创建具有相同名称的新定义之前为该定义创建一个同义词。

synonym old-foo foo
: foo ... ;

另一种方法是使用自省工具，即traverse-wordlist字。使用这个词，我们可以定义一个类似于标准化词find-name-in ( c-addr u wid -- nt|0 )的词find-name-nth-in，但它找到第n个阴影词，如下所示:

: find-name-nth-in ( c-addr1 u1 u wid -- nt|0 )
>r 1+
[: ( sd u nt -- sd u true | sd nt 0 false )
2>r 2dup r@ name>string compare if rdrop r> true exit then
r> r> 1- dup if nip then dup 0<>
;] r> traverse-wordlist ( sd u | sd nt 0 )
if 2drop 0 exit then nip nip
;

此find-name-nth-in单词返回给定单词列表中具有给定名称的单词的nt，并且之后在单词列表中定义了完全相同名称的u单词(区分大小写)。，否则为0。

测试用例:

: ?name ( nt|0 -- nt ) dup 0= -13 and throw ;
: foo ." old" ;
: foo ." new" ;
"foo" 0 forth-wordlist find-name-nth-in ?name name>interpret execute
 prints "new"
"foo" 1 forth-wordlist find-name-nth-in ?name name>interpret execute
 prints "old"

在Gforth中，单词xt-see可以用作:

"foo" 1 forth-wordlist find-name-nth-in ?name name>interpret xt-see