Prolog在递归之后一直保持初始状态

Question

我正在尝试编写一个prolog程序，我们有一个叫Neo的人试图拯救人质并将其送回一个安全的地方，这个地方被称为展台，Neo有6个动作要做，分别是：向上、向下、向左、向右、放下和搬运。我们试图找出neo可以走的所有道路，例如result(drop,result(up,result(carry,result(down,s0))))就是他可以走的道路。

canMove(hostages_loc(H), CAR):-
+ length(H, 0);
CAR > 0.
%move right
action(state(grid(H,W), neo_loc(X,Y), Hos, Booth, Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
canMove(Hos, Car),
Y < W-1,
X1 is X,
Y1 is Y+1,
NEWPATH = result(right, PATH),
NEWSTATE = state(grid(H,W), neo_loc(X1,Y1), Hos, Booth, Cap, Car),
+ member(NEWSTATE, VISITED).
%Move left
action(state(grid(H,W), neo_loc(X,Y), Hos, Booth, Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
canMove(Hos, Car),
Y > 0,
X1 is X,
Y1 is Y-1,
NEWPATH = result(left, PATH),
NEWSTATE = state(grid(H,W), neo_loc(X1,Y1), Hos, Booth, Cap, Car),
+ member(NEWSTATE, VISITED).
%Move Up
action(state(grid(H,W), neo_loc(X,Y), Hos, Booth, Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
canMove(Hos, Car),
X > 0,
X1 is X-1,
Y1 is Y,
NEWPATH = result(up, PATH),
NEWSTATE = state(grid(H,W), neo_loc(X1,Y1), Hos, Booth, Cap, Car),
+ member(NEWSTATE, VISITED).

% Move down
action(state(grid(H,W), neo_loc(X,Y), Hos, Booth, Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
canMove(Hos, Car),
X < H-1,
X1 is X+1,
Y1 is Y,
NEWPATH = result(down, PATH),
NEWSTATE = state(grid(H,W), neo_loc(X1,Y1), Hos, Booth, Cap, Car),
+ member(NEWSTATE, VISITED).
% Carry
action(state(GRID, neo_loc(X,Y), hostages_loc(H), Booth, Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
member([X,Y],H),
Car < Cap,
delete(H,[X,Y], NEWH),
NewCar is Car + 1,
NEWPATH = result(carry, PATH),
NEWSTATE = state(GRID, neo_loc(X,Y), hostages_loc(NEWH), Booth, Cap, NewCar),
+ member(NEWSTATE, VISITED).
% Drop
action(state(GRID, neo_loc(X,Y), Hos, booth(X,Y), Cap, Car), PATH , VISITED, NEWSTATE, NEWPATH):-
Car > 0,
NewCar is 0,
NEWPATH = result(drop, PATH),
NEWSTATE = state(GRID, neo_loc(X,Y), Hos, booth(X,Y), Cap, NewCar),
+ member(NEWSTATE, VISITED).
path(state(_, neo_loc(X,Y), hostages_loc([]), booth(X,Y), _, 0),PATH,_,_,NEWPATH):-
NEWPATH = PATH.
path(STATE, PATH, VISITED, NEWSTATE, NEWPATH):-
action(STATE, PATH, VISITED, NEWSTATE, NEWPATH),
path(NEWSTATE, NEWPATH, [STATE|VISITED], S, P).

这是我的代码，问题是每当程序到达的基本情况时

path(state(_, neo_loc(X,Y), hostages_loc([]), booth(X,Y), _, 0),PATH,_,_,NEWPATH):-
NEWPATH = PATH.

程序继续返回到第一个状态，并返回仅执行的第一个操作，例如，如果预期输出为result(drop,result(up,result(carry,result(down,s0))))，则仅返回result(down,s0)。路径的示例输入是：path(state(grid(2,1),neo_loc(0,0),hostages_loc([[1,0]]),booth(0,0),2,0),s0,[],NS,NP).

其中grid表示网格的大小，neo_loc表示neo在网格上的位置，hostages_loc表示需要保存的人质，booth表示展台的位置，2表示neo可以携带的最大人质数量，0表示neo实际携带的人质数量。s0是初始路径，[]表示访问状态。NS和NP是我需要的输出。

Answer 1

替换：

path(STATE, PATH, VISITED, NEWSTATE, NEWPATH):-
action(STATE, PATH, VISITED, NEWSTATE, NEWPATH),
path(NEWSTATE, NEWPATH, [STATE|VISITED], S, P).

带有：

path(STATE, PATH, VISITED, FINALSTATE, FINALPATH):-
action(STATE, PATH, VISITED, NEWSTATE, NEWPATH),
path(NEWSTATE, NEWPATH, [STATE|VISITED], FINALSTATE, FINALPATH).