同一Cypher查询中有多个匹配项的问题

Question

假设我有下面的图

CREATE 
(n1:Person {name: "David Wallace", role: "CFO", dept: "management"}),
(n2:Person {name: "Ryan Howard", role: "VP, North East Region", dept: "management"}),
(n3:Person {name: "Toby Flenderson", role: "HR Rep.", dept: "HR"}),
(n4:Person {name: "Michael Scott", role: "Regional Manager", dept: "management"}),
(n5:Person {name: "Todd Pecker", role: "Travel Sales Rep.", dept: "Sales"}),
(n6:Person {name: "Angela Martin", role: "Senior Accountant", dept: ["Accounting", "Party Planning Committee"]}),
(n7:Person {name: "Dwight Schrute", role: ["Sales", "Assistant to the Regional Manager"], dept: "Sales"}),
(n8:Person {name: "Jim Halpert", role: ["Sales", "Assistant Regional Manager"], dept: "Sales"}),
(n9:Person {name: "Pam Beesley", role: "Receptionist", dept: "Reception"}),
(n10:Person {name: "Creed Barton", role: "Quality Assurance Rep.", dept: "Quality Control"}),
(n11:Person {name: "Darryl Philbin", role: "Warehouse Foreman", dept: "Warehouse"}),
(n12:Person {name: "Kevin Malone", role: "Accountant", dept: "Accounting"}),
(n13:Person {name: "Oscar Martinez", role: "Accountant", dept: "Accounting"}),
(n14:Person {name: "Meredith Palmer", role: "Supplier Relations", dept: "Supplier Relations"}),
(n15:Person {name: "Kelly Kapoor", role: "Customer Service Rep.", dept: "Customer Service"}),
(n16:Person {name: "Jerry DiCanio", dept: "Warehouse"}),
(n17:Person {name: "Madge Madsen", dept: "Warehouse"}),
(n18:Person {name: "Lonnie Collins", dept: "Warehouse"}),
(n19:Person {name: "Andy Bernard", role: "Regional Director in Sales", dept: "Sales"}),
(n20:Person {name: "Phyllis Lapin", role: "Sales", dept: "Sales"}),
(n21:Person {name: "Stanley Hudson", role: "Sales", dept: "Sales"}),
(n1)-[:manages]->(n2),
(n2)-[:manages]->(n3),
(n2)-[:manages]->(n4),
(n2)-[:manages]->(n5),
(n4)-[:manages]->(n6),
(n4)-[:manages]->(n7),
(n4)-[:manages]->(n8),
(n4)-[:manages]->(n9),
(n4)-[:manages]->(n10),
(n4)-[:manages]->(n11),
(n4)-[:manages]->(n14),
(n4)-[:manages]->(n15),
(n6)-[:manages]->(n12),
(n6)-[:manages]->(n13),
(n8)-[:manages]->(n19),
(n11)-[:manages]->(n16),
(n11)-[:manages]->(n17),
(n11)-[:manages]->(n18),
(n19)-[:manages]->(n20),
(n19)-[:manages]->(n21);

我有以下查询

Michael直接管理的员工比Jim Halpert多吗？

我提出了以下Cypher查询

MATCH (p:Person)<-[:manages]-(n:Person)
WHERE n.name = "Michael Scott"
MATCH (q:Person)<-[:manages]-(m:Person)
WHERE m.name = "Jim Halpert"
RETURN count(p) > count(q)

查询返回false。我检查了count(p)和count(q)都是8。我想知道为什么会这样？此外，MATCH语句的作用域是什么？这意味着p和q将绑定到不同的变量(即，变量仅在MATCH语句作用域中可见；我可以对不同的MATCH语句重复使用相同的变量(？

谢谢！

Answer 1

查询中的两个匹配项正在形成一个笛卡尔乘积，为每个q返回一个p(1 x 8(。如果用Darryl Philbin代替Jim Halpert，则p和q(3 x 8(各有24个计数。

如果你运行，你会更清楚地看到发生了什么

MATCH (p:Person)<-[:manages]-(n:Person)
WHERE n.name = "Michael Scott"
MATCH (q:Person)<-[:manages]-(m:Person)
WHERE m.name = "Jim Halpert"
RETURN p.name, q.name

正如Lukasmp3所说，引入WITH将查询分解为两个不同的部分，并阻止catresian产品的形成，然后您将得到预期的答案。

Answer 2

链接更多MATCH子句时，一个很好的方法是使用WITH语句显式分离查询部分，允许您声明哪些变量要转移到下一部分。

在您的情况下：

MATCH (p:Person)<-[:manages]-(n:Person)
WHERE n.name = "Michael Scott"
WITH count(p) AS countP
MATCH (q:Person)<-[:manages]-(m:Person)
WHERE m.name = "Jim Halpert"
RETURN countP > count(q)